Gnuplot

Lämpötilan kuvaaja

gnuplot on ammattitasoinen komentorivipohjainen ohjelma funktioiden kuvaajien ja numeerisen datan piirtämiseen 2D- tai 3D-esityksiksi. Sitä käytetään yleisesti esimerkiksi tuottamaan kuvaajia tieteellisiin artikkeleihin.

Peruskäyttö

Funktion sin(x)/x kuvaaja

gnuplotin voi käynnistää komentoriviltä, jonka jälkeen gnuplot>-kehotteen perään syötetään tulostuskäskyt yksi kerrallaan. Monimutkaisemmat tulosteet kannattaa kuitenkin tehdä erillisiksi ajettaviksi tiedostoiksi.

gnuplot käynnistetään komennolla

gnuplot

jonka jälkeen aukeaa ohjelman päänäyttö, ja yleensä kerrotaan, että käytetään "x11":a eli graafista käyttöliittymää kuvaajien piirtämiseen (Gnuplot osaa piirtää tarvittaessa myös tekstimuotoisia kuvaajia):

       G N U P L O T
       --
Terminal type set to 'x11'
gnuplot>

X11:n sijaan voidaan käyttää myös wxt-päätettä, joka tarjoaa monipuolisemmat säätömahdollisuudet. Se on monesti käytössä oletuksena ja voidaan tarvittaessa ottaa käyttöön komennolla set term wxt.

Seuraavaksi voidaan kirjoittaa gnuplotin komentoja ohjelman omaan käyttöliittymään. Tavallinen kuvaaja xy-koordinaatistoon piirretään komennolla plot funktio, esimerkiksi:

gnuplot> plot sin(x)/x

Jos halutaan piirtää useampia funktioita, erotellaan ne pilkulla:

plot x,sin(x),sin(x)/x

Piirtyvässä ikkunassa kuvaajat ovat oletuksena erivärisiä ja värien selitykset löytyvät oikeasta ylänurkasta.

Merkinnät

Tavallisia matemaattisia merkintöjä ja funktioita voi käyttää normaalisti. Peruslaskutoimitukset (+-*/ ja sulut) toimivat normaalisti. Potenssiin korotuksessa käytetään kahta tähteä: funktio y=x^2 piirrettäisiin komennolla plot x**2.

Myös tavallisimmat matemaattiset funktiot toimivat totutusti, näitä ovat mm. trigonometriset funktiot (sin(x), cos(x), tan(x), sinh(x), asin(x), asinh(x) jne.) Eksponenttifunktiolle (e^x) käytetään merkintää exp(x). Täydellinen funktiolista löytyy Gnuplotin dokumentaatiosta.

Alueen rajaaminen

Piirtoalue voidaan rajata tietylle välille seuraavasti:

set xrange [0:10]

Tämä piirtäisi funktion kuvaajan, kun 0<=x<=10. Vastaavasti alue voidaan rajoittaa myös y:n arvojen suhteen komennolla

set yrange [3:4]

jolloin kuvaajasta piirrettäisiin se osa, jossa y-koordinaatti on välillä 3<=y<=4.

Piirtäminen parametriesityksestä

ggnuplotnuplot mahdollistaa myös funktioiden esittämisen parametrimuodossa. Aluksi on asetettava Gnuplot parametritilaan komennolla

set parametric

Nyt voidaan piirtää kuvaaja syntaksilla

plot [alaraja:yläraja] x(t),y(t)

Esimerkiksi piirretään ellipsin, jonka vaakasuora puoliakseli on 2 ja pystysuora 1:

plot [0:pi*2] 2*cos(t),sin(t)

Pintojen piirtäminen

Kolmiulotteisia kuvaajia on mahdollista piirtää komennolla splot. Komennolle annetaan parametrina piirrettävän pinnan lauseke muodossa f(x,y), jolloin funktion arvo on pinnan z-koordinaatti kyseisessä pisteessä. Esimerkiksi piirretään paraboloidi:

splot -x**2-y**2

Huomaa, että gnuplotin piirtämää kuvaa voi käännellä painamalla hiiren ykköspainikkeen pohjaan ja liikuttamalla hiirtä.

Pintoja voi piirtää myös parametrimuodossa, jolloin syntaksi on sama kuin kaksiulotteisessa tapauksessa mutta parametreja on kaksi: u ja v. Esimerkiksi piirretään torus:

splot [0:pi*2] (2+cos(v))*cos(u),(2+cos(v))*sin(u),sin(v)

Tasa-arvokäyrät

Tasa-arvokäyrien piirtäminen tapahtuu kytkemällä niiden piirtäminen päälle komennolla

set contour

Tämän jälkeen piirrettäessä pintaa gnuplot piirtää myös tasa-arvokäyriä. Pinta voidaan jättää piirtämättä antamalla komento

unset surface

Tasa-arvokäyrien määrään voi vaikuttaa komennolla

set cntrparam levels käyrien_määrä

Tasa-arvokäyrien määrän sijasta voi valita myös käyrien arvot:

set cntrparam levels incremental -1, 0.2, 1

Ensimmäinen luku on pienin arvo jolla käyrä piirretään, keskimmäinen luku kahden käyrän arvon erotus ja viimeinen luku suurin arvo.

Komennot

Komento	Selitys
exit/quit	Lopettaa ohjelman
cd	Vaihtaa työhakemistoa
pwd	Näyttää nykyisen hakemiston
set	Muuttaa asetuksia
show	Näyttää asetuksien nykyisiä arvoja
plot	Piirtää 2D-kuvaajan
splot	Piirtää 3D-kuvaajan
replot	Suorittaa uudelleen edellisen plot/splot-komennon
fit	Sovittaa käyrän pistejoukkoon
save	Tallentaa muuttujia, funktioita ja asetuksia
load	Lataa save-komennolla tallennetun tiedostoston
reset	Palauttaa oletusasetukset
pause	Tauko

Komennoissa ja niiden parametreissa riittää kirjoittaa jokaisen sanan alkuosaa sen verran, että alkuosa yksilöi tietyn komennon. Esimerkiksi seuraavat komennot toimivat samoin:

plot sin(x) title "Sini"
pl sin(x) t "Sini"

Ääkköset

gnuplot tukee UTF-8-merkistön käyttöä versiosta 4.4 alkaen, joten ääkköset ja muut erikoismerkit voi kirjoittaa sellaisenaan. UTF-8:aa käytetään yleensä automaattisesti oletuksena, jos myös muu käyttöympäristö käyttää sitä, mutta halutessaan UTF-8-enkoodauksen voi pakottaa päälle komentamalla aivan aluksi

set encoding utf8

Vanhemmat versiot eivät tue UTF-8-merkistöä, joten skandien ja muiden erikoismerkkien käyttö on hieman hankalaa. Skandeja ei voi syöttää suoraan tekstiin vaan ne tulee antaa numerokoodeina. Esimerkiksi 'ä':n numerokoodi on 344 joten x-akselille asetettaisiin otsikko "Jännite" komennolla

set xlabel "J\344nnite"

Huomaa, että kaikki gnuplot-päätteet (joista lisää seuraavassa kappaleessa) eivät välttämättä osaa ainakaan oletusasetuksilla näyttää ääkkösiä.

Skandien koodit ovat seuraavat:

• å - 345
• Å - 305
• ä - 344
• Ä - 304
• ö - 366
• Ö - 326

Huomaa, että merkkijono ei saa päättyä erikoismerkkiin. Esimerkiksi sana "testiä" asetettaisiin x-akselin otsikoksi lisäämällä sen perään vielä välilyönti: set xlabel "testi\344 "

Tulostus tiedostoon

gnuplot osaa piirtää kuvaajat myös tiedostoon. Se onnistuu valitsemalla päätteen (engl. terminal) tyypiksi esimerkiksi png komennolla

set term png

Muita mahdollisia arvoja ovat esimerkiksi jpeg, postscript ja latex. Täydellisen listan saat näkyviin komennolla help set term.

Tämän jälkeen asetetaan tulostettavan tiedoston nimi komennolla

set output "tiedosto.png"

Lopulta kuvaajan tulostaminen tähän tiedostoon tapahtuu normaalisti komennolla plot. Yllämainitun sijaan voit myös tulostaa kuvan vasemmasta ylälaidassa olevasta "gnuplot graph" tagista oikealla hiirennäppäimellä "options" ja sieltä "copy clipboard" . Tämän jälkeen voit siirtää kuvan grafiikkaohjelmaan normaalisti copy/paste. Tapa on helpompi erityisesti värikuvia käsitellessä.

Postscript-päätteestä

Tavallisten kuvien (jpeg, png jne) tuottamisen lisäksi käytetään yleisesti postscript-päätettä. Postscript-tiedostojen etu on se, että niissä kuva on tallennettu vektorigrafiikkana joten sitä voidaan suurentaa ja pienentää laadun kärsimättä. Erityisen suositeltavaa Postscript-kuvien käyttö on LaTeXia käytettäessä, jolloin Postscript-muotoinen tiedosto voidaan helposti liittää osaksi dokumenttia (pdflatexia käytettäessä tiedosto voidaan muuntaa ensin pdf-muotoon komennolla ps2pdf tiedosto.ps). Uusimmat Gnuplotin versiot osaavat myös tuottaa suoraan Pdf-tiedostoja (set term pdf) joita voidaan käyttää myös LaTeXin kanssa.

Postscript-päätettä käytettäessä kannattaa antaa sille asetus enhanced komennolla

set term postscript enhanced solid

jolloin käyttöön tulee ominaisuuksiltaan laajennettu Postscript-pääte. Laajennettu versio tukee mm. joitain erikoismerkkejä (kts. kappale Ääkköset) ja LaTeX-muotoiluja (esimerkiksi potenssit voidaan merkitä muodossa a^b, jolloin b päätyy yläindeksiin). Ilman valintaa solid kuvaajat tulostuvat katkoviivana.

Numeerisen datan piirtäminen ja käyrän sovitus pistejoukkoon

gnuplot osaa sovittaa mielivaltaisia käyriä pistejoukkoon ja se osaa huomioida myös pisteiden virherajat. Pisteet annetaan omassa tiedostossa, jossa jokaisella rivillä on joko välilyönnillä tai sarkaimella (tabulaattorilla) erotettuna pisteen koordinaatit ja mahdollisesti myös virherajat.

Esimerkiksi sovitetaan suora seuraavaan, suunnilleen lineaariseen pistejoukkoon. Tehdään tiedosto mittaus.dat seuraavalla tavalla:

#mittaus.dat
#x      y       xvirhe  yvirhe
3       68      0.1     1
4       71.2    0.2     2
5       70      0.15    6
5.5     76.6    0.1     0.5
7.1     81.1    0.2     1
8.2     86.5    0.2     2
9       89      2       3

Nyt tämä pistejoukko voitaisiin yksinkertaisesti piirtää plot-komennolla seuraavasti

plot "mittaus.dat"

Jolloin gnuplot piirtää pisteet ja valitsee alueen rajat siten, että kaikki pisteet mahtuvat alueelle.

Kuvaan saadaan näkymään virheet lisäämällä komennon perään tekstin with xyerrorbars. with-komennolla on mahdollista lisätä kuvaajaan muitakin elementtejä. Esimerkiksi seuraavat elementit ovat mahdollisia:

Elementti	Selitys
xyerrorbars	Virherajat x- ja y-suunnassa
xerrorbars, yerrorbars	Vain x- tai y-suuntaiset virherajat
lines	Viiva pisteestä pisteeseen
boxxyerrorbars	Virherajat laatikkoina
points	Datapisteet (oletus)

Varsinainen sovitus

Jos piirrämme pistejoukkoon käyrän komennolla

plot "mittaus.dat" with lines

huomataan, että pisteet ovat likimain samalla suoralla, mutta kuvaajassa pisteet on vaan yhdistetty toisiinsa mutkittelevalla viivalla. Voimme kuitenkin sovittaa tähän pistejoukkoon suoran tai minkä tahansa mielivaltaisen funktion seuraavasti.

Määritellään ensin sovitettava funktio f(x):

f(x)=A*x+B

y=A*x+B siis on suoran yhtälö, joten olemme sovittamassa suoraa. Gnuplot selvittää vakiot A ja B.

Varsinainen sovitus tehdään komennolla

fit f(x) "mittaus.dat" via A,B

Eli fit-komennolle annetaan funktio, joka sovitetaan pistejoukkoon ja via-komennolla kerrotaan vakiot, jotka gnuplotin tulee selvittää.

Tämä komento tulostaa paljon tekstiä kertoen etenemisestään ja kertoo lopulta, millaiseen käyrään se päätyi:

Final set of parameters            Asymptotic Standard Error
=======================            ==========================

A               = 3.66307          +/- 0.3708       (10.12%)
B               = 55.6119          +/- 2.34         (4.208%)


correlation matrix of the fit parameters:

               A      B      
A               1.000 
B              -0.946  1.000 

Eli pistejoukkoon sovitetun suoran yhtälö on 3,66307*x+55,6119. Kulmakertoimen virhe on +/- 0,3708 ja vakiotermin +/- 2,34.

Nyt kun sovitus on tehty, voidaan sovitettu kuvaaja piirtää komennolla

plot f(x)

Lopullinen kuvaaja

Sillä fit-komento on asettanut f(x):n vakioille A ja B arvot. Jos samaan kuvaan halutaan piirtää myös datapisteet ja niiden virherajat, komento on

plot "mittaus.dat" with xyerrorbars,f(x)

Tässä siis piirretään kaksi kuvaajaa, jotka erotetaan toisistaan pilkulla.

Virherajojen huomioiminen sovituksessa

Oletuksena gnuplot ei huomioi pisteille asetettuja virhetermejä käyrää sovittaessaan. Sovitukseen voidaan kuitenkin asettaa jokaista pisteparia vastaamaan tietty painokerroin joka kuvaa pisteen virherajoja. Kuten monet muutkin sovitusohjelmat, gnuplot osaa huomioida vain yhden virhetermin (eli painokertoimen). Jos sekä x:n että y:n virhe pitää huomioida sovituksessa, on käyttäjän yhdistettävä ne ensin käsin sopivaksi katsomallaan tavalla. gnuplot asettaa pisteparin painokertoimeksi sovituksessa 1/s^2, missä s on annettu virhe.

Käytännössä tämä tapahtuu siten, että sovituskomennossa kerrotaan gnuplotille, missä tiedoston sarakkeessa virhetermi on. Jos edellä olevassa esimerkissä päättäisimme, että voimme jättää x-koordinaatin virheen huomioon ottamatta, kertoisimme virheen olevan tiedoston 4. sarakkeessa jolloin sovitus tapahtuisi komennolla

fit f(x) "mittaus.dat" using 1:2:4 via A,B

Tässä siis parametri using 1:2:4 kuvaa tiedoston rakenteen: ensimmäisessä sarakkeessa on x-koordinaatti, toisessa y-koordinaatti ja neljännessä y-koordinaatin keskihajonta.

Lisätietoja sovitustoiminnosta löytyy gnuplotin ohjeista komennolla

help fit

using-valitsimesta

Using-valitsimella on mahdollista tehdä muutakin kuin vain kertoa, mistä sarakkeesta datapisteitä otetaan. Sen lisäksi se mahdollistaa datapisteiden laskemisen tiedostossa olevien arvojen perusteella.

Esimerkiksi jos y-koordinaatti olisi tiedostossa senttimetreinä ja se haluttaisiin kuvaajaan metreinä, täytyisi jokainen y-sarakkeen arvo jakaa sadalla. Tämän tekeminen käsin käy nopeasti työlääksi, joten tehdään muunnos lennossa käyttäen using-valitsinta:

plot "mittaus.dat" using 1:($2/100)

Eli tässä on sarakkeen sijasta kirjoitettu sulkuihin lauseke, jolla y-koordinaatti lasketaan. $2 viittaa tiedoston toisen sarakkeen arvoon (vrt. edellä annettiin pelkkä numero 2 kun arvo otettiin suoraan tästä sarakkeesta). Suluissa annettavassa lausekkeessa voidaan käyttää vapaasti gnuplotin komentoja (esimerkiksi toimisi using 1:($1*sin($2))).

Katso myös

• Octave
• QtiPlot

Aiheesta muualla

• Ohjelman kotisivu
• Jyväskylän yliopiston fysiikan laitoksen Gnuplot-opas